ホーム > ソフトウェア > 掲示板
| タイトル | ： Re: インフォメーションの予定が消えます。 |
| 投稿日 | ： 2008/10/27(Mon) 01:15 |
| 投稿者 | ： JJ |
これは役立つソフトですが、このバグは致命的ですね。
私も何度もやられました。
そろそろバグが直っているかなと覗きにきましたが、、、未解決のようですね。
ちなみに私は以下のように独自でバックアップをとるようにしています。
スタートアップ時の inform.exe の起動前に以下のVBScriptを実行してinform.iniのバックアップします。
バックアップファイル名がYYYYMMDD.bak形式で５日分ローテートしています。
ご利用は自己責任でお願いします。
----------
Option Explicit
Const INFORM_DIR = "X:\Program Files\inform\" 'インフォメーションのディレクトリ
Const INFORM_INI = "inform.ini" 'バックアップ対象ファイル
Const BACKUP_EXT = ".bak" 'バックアップファイルの拡張子
Const BACKUP_CNT = 5 'バックアップ世代管理数
Dim fs
Set fs = CreateObject("Scripting.FileSystemObject")
Dim todayStamp
todayStamp = FormatDateStamp( Date, "YYYYMMDD" )
Dim originalFile, copyFile
originalFile = INFORM_DIR & INFORM_INI
copyFile = INFORM_DIR & todayStamp & BACKUP_EXT
If Not fs.FileExists( copyFile ) AND Not fs.FolderExists( copyFile ) Then
fs.CopyFile originalFile, copyFile
End If
DelOldestFile INFORM_DIR, BACKUP_CNT
Function FormatDateStamp(dt, format)
format = Replace(format, "YYYY", Year(dt))
format = Replace(format, "YY", Right( Year(dt), 2 ))
format = Replace(format, "MM", Right( Month(dt) + 100, 2 ))
format = Replace(format, "M", Month(dt))
format = Replace(format, "DD", Right( Day(dt) + 100, 2 ))
format = Replace(format, "D", Day(dt))
FormatDateStamp = format
End Function
Function DelOldestFile(dir, limit)
Dim dirObj, fileObj, delObj, fileCnt, oldDate
Set dirObj = fs.GetFolder(dir)
oldDate = Now()
fileCnt = 0
For Each fileObj In dirObj.Files
If Right(fileObj.Name, 4) = BACKUP_EXT Then
If fileObj.DateCreated < oldDate Then
oldDate = fileObj.DateCreated
Set delObj = fileObj
End If
fileCnt = fileCnt + 1
End If
Next
If fileCnt > limit Then
delObj.Delete
End If
End Function
----------
- 関連一覧ツリー
（ をクリックするとツリー全体を一括表示します）
- 返信フォーム
（この記事に返信する場合は下記フォームから投稿して下さい）
|
